forum.clarionlife.net

Код: Выделить всё

  CURRENT_USER_STORE = 2
  MY_STORE = "My"
  STORE_OPEN_READ_ONLY = 0
  CAPICOM_CERTIFICATE_FIND_SHA1_HASH = 0
  CertSHA1Hash = "........"  'отпечаток из свойств сертификата
  CADES_BES = 1
  CAPICOM_ENDCODE_BASE64 = 0    'преобразование выходного файла в base64
  
  Set objArgs = WScript.Arguments  'получаем аргументы
  InFileName  = objArgs(0)      'имя подписываемого файла 
  OutFileName = objArgs(1)      'имя подписанного файла
  bDetached =   objArgs(2)      '0 - совмещенная, 1 - отделенная подпись

  'поиск сертификата в хранилище по отпечатку
  Set Store = CreateObject ("CADESCOM.Store")   
  Store.Open CURRENT_USER_STORE, MY_STORE, STORE_OPEN_READ_ONLY
  Set Certs = Store.Certificates.Find(CAPICOM_CERTIFICATE_FIND_SHA1_HASH, CStr (CertSHA1Hash))
  if Certs.Count > 0 Then
     Set GetSigningCert = Certs.Item (1) 
  else
     Set GetSigningCert = Nothing
  end if
  Store = Unassgned 

  if not GetSigningCert is nothing Then   'если сертификат найден, то подписываем
     set InStream = CreateObject("AdoDB.Stream")  'читаем исходный файл
     InStream.Type = 1
     InStream.Mode = 3
     InStream.Open()
     InStream.LoadFromFile(InFileName)
     InData = InStream.Read(-1)
  
     Set Signer = CreateObject ("CADESCOM.CpSigner")   'подписываем
     Signer.Certificate = GetSigningCert
     Signer.Options = 2
     Set SignedData = CreateObject ("CADESCOM.CadesSignedData")
     SignedData.Content = InData
     OutSignedData = SignedData.SignCades(Signer,CADES_BES,bDetached,CAPICOM_ENDCODE_BASE64)

     set OutStream = CreateObject("AdoDB.Stream")  'сохраняем подписанный файл или подпись
     OutStream.CharSet = "utf-8"
     OutStream.Type = 2
     OutStream.Mode = 3
     OutStream.Open()
     OutStream.WriteText(OutSignedData)
     OutStream.SaveToFile OutFileName,2 
     OutStream.Close()
     InStream.Close()

     SignedData = Unassgned
     Signer = Unassigned
     FileIn = Unassigned
     FileOut= Unassigned
  end if

Код: Выделить всё

c:\windows\sysWow64\wscript.exe "полный путь в файлу test.vbs"