forum.clarionlife.net

Код: Выделить всё

P   Class(DumpClass)
    End
....
!    Регистрация хранимых объектов (Очереди, группы, просто переменные 
     P.AddField('ZTstQ',TstQ)
     P.AddField('ResQ',ResQ)
     P.AddField('Qlist',QList)
     P.AddField('QGroup',QGroup)
.... 
!    Чтение блоба 
     P.LoadBlob(Ses:Info)

.... 
!     Запись блоба 
      P.SaveBlob(Ses:Info)

Код: Выделить всё

  PROGRAM

SomeGrp                       GROUP, TYPE
s1                              STRING(20)
l1                              LONG
                              END

SomeQue                       QUEUE(SomeGrp), TYPE
                              END

  MAP
    Que2String(SomeQue q), *STRING
    String2Que(STRING  s, *SomeQue q)
  END


myQ                           QUEUE(SomeQue)
                              END

qBuf                          &STRING
ndx                           LONG, AUTO

  CODE
  !-- test data
  myQ.l1 = 1
  myQ.s1 = 'First'
  ADD(myQ)
  myQ.l1 = 2
  myQ.s1 = 'Second'
  ADD(myQ)

  !-- byte serialization
  qBuf &= Que2String(myQ)

  !-- delete all records
  FREE(myQ)
  CLEAR(myQ)

  !-- deserialize
  String2Que(qBuf, myQ)

  !-- Test
  LOOP ndx = 1 TO RECORDS(myQ)
    GET(myQ, ndx)
    MESSAGE(myQ.l1 &': '& myQ.s1)
  END

  !-- cleanup
  DISPOSE(qBuf)
  
Que2String                    PROCEDURE(SomeQue q)
sref                            &STRING
grp                             LIKE(SomeGrp)
nrecs                           LONG, AUTO
qIndex                          LONG, AUTO
slice1                          LONG, AUTO
slice2                          LONG, AUTO
  CODE
  nrecs = RECORDS(q)
  sref &= NEW STRING(nrecs * LEN(grp))
  
  slice1 = 1
  slice2 = LEN(grp)
  
  LOOP qIndex = 1 TO nrecs
    GET(q, qIndex)
    grp = q
    sref[slice1 : slice2] = grp
    slice1 += LEN(grp)
    slice2 += LEN(grp)
  END
  
  RETURN sref
  
String2Que                    PROCEDURE(STRING  s, *SomeQue q)
grp                             LIKE(SomeGrp)
nrecs                           LONG, AUTO
qIndex                          LONG, AUTO
slice1                          LONG, AUTO
slice2                          LONG, AUTO
  CODE
  nrecs = LEN(s) / LEN(grp)
  slice1 = 1
  slice2 = LEN(grp)
  LOOP qIndex = 1 TO nrecs
    grp = s[slice1 : slice2]
    q = grp
    ADD(q)
    slice1 += LEN(grp)
    slice2 += LEN(grp)
  END