forum.clarionlife.net

Код: Выделить всё

ReqSNMPSystem        PROCEDURE  (STRING IP,  LONG SWID, LONG MODID, STRING Comm) ! Declare Procedure
Window WINDOW('WGetSNMP'),AT(,,131,60),FONT('MS Sans Serif',8,,FONT:regular),IMM,SYSTEM,GRAY,DOUBLE,MDI
       BUTTON('&OK'),AT(53,43,35,14),USE(?OkButton),LEFT,DEFAULT
     END

SNMPRequestOids             SNMPRequestOidsType ! Рабочая Очередь, использую для однотипности кода, 
                                        ! конкретно здесь она заполняется из объявленных переменных

MIBsysDescr     STRING('.1.3.6.1.2.1.1.1')
MIBsysUpTime    STRING('.1.3.6.1.2.1.1.3')
MIBsysContact   STRING('.1.3.6.1.2.1.1.4')
MIBsysName      STRING('.1.3.6.1.2.1.1.5')
MIBsysLocation  STRING('.1.3.6.1.2.1.1.6')


LocResults        QUEUE	! Очередь для обмена инфой с классом GetSNMPClass
Id_Descr            LONG
ResultQueue         &SNMPResultQueueType
                  END
SNMP              GetSNMPClass ! Объявляем класс

SWI_ID            LONG
Loc:Count         LONG
LocIdx            LONG
FilesOpened     BYTE(0)

  CODE
  OPEN(Window)
  DISPLAY
  DO OpenFiles

  !Заполняем рабочую очередь
  FREE(SNMPRequestOids)
  SNMPRequestOids.Id    = 1
  SNMPRequestOids.Cnv   = 1
  SNMPRequestOids.NameOID = 'sysDescr'
  SNMPRequestOids.Oid   = MIBsysDescr
  ADD(SNMPRequestOids)
  SNMPRequestOids.Id    = 2
  SNMPRequestOids.Cnv   = 1
  SNMPRequestOids.NameOID = 'sysName'
  SNMPRequestOids.Oid   = MIBsysName
  ADD(SNMPRequestOids)
  SNMPRequestOids.Id    = 3
  SNMPRequestOids.Cnv   = 1
  SNMPRequestOids.NameOID = 'sysContact'
  SNMPRequestOids.Oid   = MIBsysContact
  ADD(SNMPRequestOids)
  SNMPRequestOids.Id    = 4
  SNMPRequestOids.Cnv   = 1
  SNMPRequestOids.NameOID = 'sysLocation'
  SNMPRequestOids.Oid   = MIBsysLocation
  ADD(SNMPRequestOids)
  SNMPRequestOids.Id    = 5
  SNMPRequestOids.Cnv   = 5
  SNMPRequestOids.NameOID = 'sysUpTime'
  SNMPRequestOids.Oid   = MIBsysUpTime
  ADD(SNMPRequestOids)

  SWI_ID = SWID

  ACCEPT
    CASE EVENT()
    OF EVENT:OpenWindow
      SNMP.Init(IP,comm)  ! Инициализация класса, подаем ему IP адрес и Community, обычно оно = 'public' 
      ! Заполняем очередь для обмена с SNMP, хранения полученного результата и походу запрашиваем инфу с SNMP
      LOOP Loc:Count = 1 TO RECORDS(SNMPRequestOids)
        GET(SNMPRequestOids,Loc:Count)
        LocResults.Id_Descr = SNMPRequestOids.Id
        LocResults.ResultQueue &= NEW(SNMPResultQueueType)
        ADD(LocResults)
        SNMP.Run(SNMPRequestOids.Cnv, SNMPRequestOids.NameOID, SNMPRequestOids.Oid, LocResults.ResultQueue)
      END
      SNMP.Kill ! прощаемся с классом
      BREAK
    END
  END
  FREE(SNMPRequestOids)
  ! Здесь у меня полученный результат записывается в таблицу и в лог файл, и по ходу очищается очередь
  SWI:ID = SWI_ID
  GET(Switch,SWI:BY_ID)
  IF NOT ERRORCODE()
    CLEAR(SWI:SystemInfo)
    LOOP i# = 1 TO RECORDS(LocResults)
      LocResults.Id_Descr = i#
      GET(LocResults,LocResults.Id_Descr)
      IF NOT ERRORCODE()
        LOOP LocIdx = 1 TO RECORDS(LocResults.ResultQueue)
          GET(LocResults.ResultQueue,1)
          IF NOT(LocResults.ResultQueue.Value &= NULL)
            IF i# = 5          
              SWI:SystemUpTime = '||' & LocResults.ResultQueue.Value
              SaveLog('RS', IP & ' ' & SWI:SystemUpTime)
              DISPOSE(LocResults.ResultQueue.Value)
            ELSE
              SWI:SystemInfo = CLIP(SWI:SystemInfo) & '||' & LocResults.ResultQueue.Value
              SaveLog('RS', IP & ' ' & SWI:SystemInfo)
              DISPOSE(LocResults.ResultQueue.Value)
            END
          END
          IF NOT(LocResults.ResultQueue.Oid &= NULL)
            DISPOSE(LocResults.ResultQueue.Oid)
          END
          DELETE(LocResults.ResultQueue)
        END
        FREE(LocResults.ResultQueue)
        DISPOSE(LocResults.ResultQueue)
        DELETE(LocResults)
      END
    END
    PUT(Switch)
    IF ERRORCODE()
       SaveLog('RS', IP & ' ERROR ' & ERROR())
    END  
    SaveLog('RS', IP & ' --- ' & SWI:SystemInfo)

    PUT(Switch)
  END
  DO CloseFiles
  CLOSE(Window)

!--------------------------------------
OpenFiles  ROUTINE
  Access:Switch.Open                                       ! Open File referenced in 'Other Files' so need to inform its FileManager
  Access:Switch.UseFile                                    ! Use File referenced in 'Other Files' so need to inform its FileManager
  FilesOpened = True
!--------------------------------------
CloseFiles ROUTINE
  IF FilesOpened THEN
     Access:Switch.Close
     FilesOpened = False
  END

Код: Выделить всё

MacBook-Air-mixer:~ mixer$ snmpwalk -v1 -c public 192.168.1.8 .1.3.6.1.2.1.1.1
SNMPv2-MIB::sysDescr.0 = STRING: Linux DiskStation 2.6.32.12 #5592 Wed Aug 19 13:37:12 CST 2015 armv5tel

MacBook-Air-mixer:~ mixer$ snmpwalk -v1 -c public 192.168.1.8 .1.3.6.1.2.1.1.3
DISMAN-EVENT-MIB::sysUpTimeInstance = Timeticks: (33899665) 3 days, 22:09:56.65