forum.clarionlife.net

Код: Выделить всё

! --- Вызов

  Map
     GetMyStatusPrinter(*cstring,*byte,*cstring)
  end
  
  ! Ставим в окне опрос текущего принтера по таймеру раз в секунду   

  Loc:PrinterName = Printer{PropPrint:Device}
  GetMyStatusPrinter(Loc:PrinterName,Loc:Status,Loc:NameStatus)
  Message(Loc:Status & '|' & Loc:NameStatus) ! По Loc:Status красим сообщение, выводим картинки и т.д. - по вкусу
  
! --- Процедура

GetMyStatusPrinter   PROCEDURE  (xName_,xStatus_,xNameSt_)

  Map
    Module('Windows')

    WinOpenPrinter     (*CSTRING pPrinterName,       | printer or server name
                        *LONG phPrinter,             | printer or server handle
                        LONG pDefault                | printer defaults
                       ),BOOL,PASCAL,RAW,NAME('OpenPrinterA')

    WinGetPrinter      (LONG hPrinter,               | handle to printer
                        LONG Level,                  | information level
                        *? pPrinter,                 | printer information buffer
                        LONG cbBuf,                  | size of buffer
                        *LONG pcbNeeded              | bytes received or required
                       ),BOOL,PASCAL,RAW,NAME('GetPrinterA')

    WinClosePrinter    ( LONG hPrinter ),BOOL,RAW,PASCAL,PROC,Name('ClosePrinter')
  end
 end

Loc:Buffer     Group
PrnStatus        Long
                   end

Loc:hPrinter   Long
Loc:Size         Long

PRINTER_STATUS_READY             EQUATE(      0h)
PRINTER_STATUS_PAUSED            EQUATE(      1h)
PRINTER_STATUS_ERROR             EQUATE(      2h)
PRINTER_STATUS_PENDING_DELETION  EQUATE(      4h)
PRINTER_STATUS_PAPER_JAM         EQUATE(      8h)
PRINTER_STATUS_PAPER_OUT         EQUATE(     10h)
PRINTER_STATUS_MANUAL_FEED       EQUATE(     20h)
PRINTER_STATUS_PAPER_PROBLEM     EQUATE(     40h)
PRINTER_STATUS_OFFLINE           EQUATE(     80h)
PRINTER_STATUS_IO_ACTIVE         EQUATE(    100h)
PRINTER_STATUS_BUSY              EQUATE(    200h)
PRINTER_STATUS_PRINTING          EQUATE(    400h)
PRINTER_STATUS_OUTPUT_BIN_FULL   EQUATE(    800h)
PRINTER_STATUS_NOT_AVAILABLE     EQUATE(   1000h)
PRINTER_STATUS_WAITING           EQUATE(   2000h)
PRINTER_STATUS_PROCESSING        EQUATE(   4000h)
PRINTER_STATUS_INITIALIZING      EQUATE(   8000h)
PRINTER_STATUS_WARMING_UP        EQUATE(  10000h)
PRINTER_STATUS_TONER_LOW         EQUATE(  20000h)
PRINTER_STATUS_NO_TONER          EQUATE(  40000h)
PRINTER_STATUS_PAGE_PUNT         EQUATE(  80000h)
PRINTER_STATUS_USER_INTERVENTION EQUATE( 100000h)
PRINTER_STATUS_OUT_OF_MEMORY     EQUATE( 200000h)
PRINTER_STATUS_DOOR_OPEN         EQUATE( 400000h)
PRINTER_STATUS_SERVER_UNKNOWN    EQUATE( 800000h)
PRINTER_STATUS_POWER_SAVE        EQUATE(1000000h)

  CODE
  
  xStatus_ = 0        ! Unknow status printer
  xNameSt_ = '???'   ! ХЗ состояние

  If WinOpenPrinter(xName_,Loc:hPrinter,0)
     If WinGetPrinter(Loc:hPrinter,6,Loc:Buffer,Size(Loc:Buffer),Loc:Size)

        Case Loc:Buffer.PrnStatus
        Of PRINTER_STATUS_READY
           xStatus_ = 1
           xNameSt_ = 'Готов'
        Of PRINTER_STATUS_PAUSED
           xStatus_ = 2
           xNameSt_ = 'Приостановлен'
        Of PRINTER_STATUS_ERROR
           xStatus_ = 2
           xNameSt_ = 'Ошибка'
        Of PRINTER_STATUS_PENDING_DELETION
           xStatus_ = 2
           xNameSt_ = 'Состояние ожидания удаления'
        Of PRINTER_STATUS_PAPER_JAM
           xStatus_ = 2
           xNameSt_ = 'Замята бумага'
        Of PRINTER_STATUS_PAPER_OUT
           xStatus_ = 2
           xNameSt_ = 'Нет бумаги'
        Of PRINTER_STATUS_MANUAL_FEED
           xStatus_ = 1
           xNameSt_ = 'Включена ручная подача бумаги'
        Of PRINTER_STATUS_PAPER_PROBLEM
           xStatus_ = 2
           xNameSt_ = 'Проблема с бумагой'
        Of PRINTER_STATUS_OFFLINE
           xStatus_ = 2
           xNameSt_ = 'Отключен'
        Of PRINTER_STATUS_IO_ACTIVE
           xStatus_ = 1
           xNameSt_ = 'Идет обмен данными'
        Of PRINTER_STATUS_BUSY
           xStatus_ = 2
           xNameSt_ = 'Занят'
        Of PRINTER_STATUS_PRINTING
           xStatus_ = 1
           xNameSt_ = 'Печатает'
        Of PRINTER_STATUS_OUTPUT_BIN_FULL
           xStatus_ = 2
           xNameSt_ = 'Заполнен выходной лоток'
        Of PRINTER_STATUS_NOT_AVAILABLE
           xStatus_ = 2
           xNameSt_ = 'Не доступен для печати'
        Of PRINTER_STATUS_WAITING
           xStatus_ = 2
           xNameSt_ = 'В ожидании'
        Of PRINTER_STATUS_PROCESSING
           xStatus_ = 1
           xNameSt_ = 'Обработка команды'
        Of PRINTER_STATUS_INITIALIZING
           xStatus_ = 2
           xNameSt_ = 'Инициализация ...'
        Of PRINTER_STATUS_WARMING_UP
           xStatus_ = 2
           xNameSt_ = 'Прогревается ...'
        Of PRINTER_STATUS_TONER_LOW
           xStatus_ = 1
           xNameSt_ = 'Мало тонера'
        Of PRINTER_STATUS_NO_TONER
           xStatus_ = 2
           xNameSt_ = 'Закончился тонер'
        Of PRINTER_STATUS_PAGE_PUNT
           xStatus_ = 2
           xNameSt_ = 'Не может напечатать текущую страницу'
        Of PRINTER_STATUS_USER_INTERVENTION
           xStatus_ = 2
           xNameSt_ = 'Ошибка, требующая вмешательства пользователя'
        Of PRINTER_STATUS_OUT_OF_MEMORY
           xStatus_ = 2
           xNameSt_ = 'Закончилась память'
        Of PRINTER_STATUS_DOOR_OPEN
           xStatus_ = 2
           xNameSt_ = 'Открыта дверка принтера'
        Of PRINTER_STATUS_SERVER_UNKNOWN
           xStatus_ = 0
           xNameSt_ = 'Состояние неизвестно'
        Of PRINTER_STATUS_POWER_SAVE
           xStatus_ = 1
           xNameSt_ = 'Находится в состоянии экономии энергии'
        end
     end

     If WinClosePrinter(Loc:hPrinter).
  end