forum.clarionlife.net

Код: Выделить всё

                   PROGRAM
                   MAP
                   END

Window WINDOW('Caption'),AT(,,307,161),FONT('MS Sans Serif',8,,FONT:regular),SYSTEM,GRAY,RESIZE
       LIST,AT(0,0),USE(?List),FULL,HVSCROLL
     END
      !LIST,AT(0,0),USE(?List),FULL,HVSCROLL,FORMAT('50L(2)|M~Суть~10L(2)Y~1~@P PB@10L(2)Y~2~@P PB@10L(2)Y~3~@P PB@')

DefaultFormat      EQUATE('50L(2)|FM~Суть~')
LOC:Format         STRING(4096)

DataQueue          QUEUE
Line                 STRING(4096)
                   END

 CODE
 OPEN(Window)
 LOC:Format = DefaultFormat
 LOOP W# = 1 TO 100                !ширина     !номер !формат
   LOC:Format = CLIP(LOC:Format) & '13L(2)Y~' & W# & '~@P PB@'
 END
 ?List{PROP:Lineheight} = 10
 ?List{PROP:Format} = LOC:Format
 ?List{PROP:From} = DataQueue
 ! стилей можно наделать море разных.
 ?List{PROPSTYLE:BackColor,1} = COLOR:Red
 ?List{PROPSTYLE:BackSelected,1} = COLOR:Red
 ?List{PROPSTYLE:BackColor,2} = COLOR:Blue
 ?List{PROPSTYLE:BackSelected,2} = COLOR:Blue
 ?List{PROPSTYLE:BackColor,3} = COLOR:None
 ?List{PROPSTYLE:BackSelected,3} = COLOR:None
 LOOP W# = 1 TO 1000
   CLEAR(DataQueue)
   DataQueue.Line = 'Строка #' & FORMAT(W#,@N04)
   LOOP 99 TIMES
     ! набиваем ячейки. проявив смекалку можно сделать диаграмму
     ! RANDOM(1,3) - стиль из описанных выше
     ! |1| - просто заполнитель т.к. пусто не прокатывало у меня
     ! разбираться не стал.
     DataQueue.Line = CLIP(DataQueue.Line)&'|1|'&RANDOM(1,3)
   END
   ! делаем ячейку 100 чистой... для красоты
   DataQueue.Line = CLIP(DataQueue.Line)&'|1|0'
   ADD(DataQueue)
 END
 ACCEPT
 END
 CLOSE(Window)