Страница 1 из 1

Ищу современный аналог nnbackup

Добавлено: 15 Октябрь 2019, 10:18
Admin
nnbackup на windows 10 иногда после архивации зависает.

Ищу современный аналог nnbackup

Добавлено: 15 Октябрь 2019, 14:46
gopstop2007
пользуюсь таким - Exiland Backup Professional
пользуюсь ~5 лет, поставил и забыл
до него перебрал х*еву тучу программ, то функционала мало, то проблемы с надежностью

Ищу современный аналог nnbackup

Добавлено: 15 Октябрь 2019, 16:05
Admin
Понятно, спасибо. Платная программа. Хотелось бы фри вариант.
Не найду попробую костылить на pkzip и xcopy.

Ищу современный аналог nnbackup

Добавлено: 16 Октябрь 2019, 2:50
Admin
Вот так обошелся

Код: Выделить всё

@echo off
@rem локальная папка с архивами
@set source="zip"

@rem удаленная папка с архивами
@set destination="c:\myprog\1"

@rem формирование имени файла
@set d1=%date:~6,4%-%date:~3,2%-%date:~0,2%
@set t1=%time:~0,2%
@set t2=%time:~3,2%
@set t3=%time:~6,2%
@if %t1% lss 10 (set t1=0%time:~1,1%)
@set filename=%source%\%d1% %t1%_%t2%_%t3%.zip

@rem создаем папку с архивами
@mkdir %source%
@rem создаем архив
@pkzip250 -add -rec -dir "%filename%" -include=@LIST.TXT -exclude=@XLIST.TXT
@rem удаляем старые архивы
@forfiles.exe /P %source%\ /M *.zip /D -90 /C "cmd /c del @FILE /q /f"
@rem синхронизируем локальную и удаленную папку
@robocopy "%source% " "%destination% " *.zip /MIR /FFT /Z /XA:H /W:5
robocopy входит в состав Windows 10. Включаемые и исключаемые файлы находятся соответственно в LIST.TXT и XLIST.TXT

Ищу современный аналог nnbackup

Добавлено: 16 Октябрь 2019, 11:31
Yufil
https://ru.fbackup.com/ не устроит? Когда-то юзал, сейчас пользую небесплатный KLSBackup

Ищу современный аналог nnbackup

Добавлено: 16 Октябрь 2019, 13:04
Admin
Ребят это все очень навороченные версии. Мне то просто нужно папку с аппликашкой забекапить.
И к примеру хранить бекапы дней 100 или последних 20-30 копий.
Ставить для этого тулзу с размером инсталяшки 80мб по моему через чур :)

Ищу современный аналог nnbackup

Добавлено: 16 Октябрь 2019, 13:28
Yufil
Тогда батничек и архиватор 7z с правильно установленными параметрами :). Или погугли Python backup script для развлечения

Ищу современный аналог nnbackup

Добавлено: 18 Октябрь 2019, 4:24
Admin
Добавил режим в котором архивы удаляются не по дате а по количеству хранимых.

Код: Выделить всё

@echo off

@rem количество дней. сколько хранить архивы
@rem удалять старые по дням del_mode=1
@rem удалять старые по количеству файлов del_mode=2
@set del_mode=2
@set arc_days=180
@set arc_counter=4

@rem локальная папка с архивами
@set source="zip"

@rem удаленная папка с архивами
@set destination="c:\1"

@rem формирование имени файла
@set d1=%date:~6,4%-%date:~3,2%-%date:~0,2%
@set t1=%time:~0,2%
@set t2=%time:~3,2%
@set t3=%time:~6,2%
@if %t1% lss 10 (set t1=0%time:~1,1%)
@set filename=%source%\%d1% %t1%_%t2%_%t3%.zip

@rem создаем папку с архивами
@mkdir %source%

@rem создаем архив
@pkzip250 -add -rec -dir "%filename%" -include=@LIST.TXT -exclude=@XLIST.TXT

@rem удаляем старые архивы
@if %del_mode% == 1 (@goto mode1)
@if %del_mode% == 2 (@goto mode2)
@goto end_mode

:mode1
@forfiles.exe /P %source%\ /M *.zip /D -%arc_days% /C "cmd /c del @FILE /q /f"
@goto end_mode

:mode2
setlocal enableextensions enabledelayedexpansion
for /f "skip=%arc_counter% usebackq delims=" %%i in (
  `dir /b /a:-d /o:-d /t:w "%source%"`
) do del /f /q "%source%\%%~i"
endlocal
@goto end_mode

:end_mode

@rem синхронизируем локальную и удаленную папку
@robocopy "%source% " "%destination% " *.zip /MIR /FFT /Z /XA:H /W:5